Funzione CreateUnoServiceWithArguments

Istanzia un servizio UNO con ProcessServiceManager, includendo degli argomenti supplementari facoltativi.

Sintassi:


    CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object
  
tip

I servizi UNO che possono essere usati con la funzione CreateUnoServiceWithArguments sono identificabili in base ai nomi dei metodi i cui nomi seguono lo schema createInstanceWith.. o createWith...


Return type:

Object

note

Per un elenco di tutti i servizi disponibili visitare la pagina della guida di riferimento del Modulo com::sun::star.


Parametri:

Nome

Tipo

Descrizione

ServiceName

String

The UNO service name to be created.

Arguments

Variant

One to many arguments that specify the instance of the service. Arguments are stored as a one dimensional array, according to their positions in the constructor method definition.


Esempio:

The com.sun.star.ui.dialogs.FilePicker example below displays a built-in LibreOfficeDev Save As dialog with two extra controls: a listbox and a checkbox.


    Sub FileSaveAsDialog()
       td = com.sun.star.ui.dialogs.TemplateDescription
       options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
       dlg = CreateUnoServiceWithArguments( _
          "com.sun.star.ui.dialogs.FilePicker", _
          Array(options))
       dlg.execute()
    End Sub ' FileSaveAsDialog
  

Le finestre di dialogo dei file, come Apri, Salva con nome e simili, sono disponibili in due varianti:

Usare - LibreOfficeDev - Generale per alternare da un tipo all'altro.

tip

I servizi UNO hanno un'estesa documentazione online sul sito api.libreoffice.org. Per saperne di più sui metodi forniti dal servizio usato nell'esempio qui sopra visitare la pagina della guida di riferimento FilePicker Service.


Esempio:

Il codice seguente usa il servizio com.sun.star.security.DocumentDigitalSignatures per firmare il documento corrente:


Sub  SignCurrentDocDialog
   Dim pv(0) as new com.sun.star.beans.PropertyValue
   pv(0).Name  = "StorageFormat"
   pv(0).Value = "ZipFormat"
   mode = com.sun.star.embed.ElementModes
   sf = CreateUnoService("com.sun.star.embed.StorageFactory")
   storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
   dds = CreateUnoServiceWithArguments( _
      "com.sun.star.security.DocumentDigitalSignatures", _
      Array("1.2", True)) 
   dds.signDocumentContent(storage, Null)
End Sub ' SignCurrentDocDialog

I metodi costruttori CreateWithVersion e createWithVersionAndValidSignature nel servizio UNO com.sun.star.security.DocumentDigitalSignatures indicano due modi diversi per istanziare questo servizio con la funzione CreateUnoServiceWithArguments.