Contents

# LET

Assigns names to calculation results. This allows storing intermediate calculations, values, or defining names inside a formula. These names only apply within the scope of the LET function.

### Syntax

=LET(Name1; Name_value1; Calculation_or_Name2 [; Name_value2; Calculation_or_Name3 [; ...]])

Name1: the first name to assign. Must start with a letter. Cannot be the output of a formula or conflict with range syntax.

Name1 must follow the naming rules of LibreOfficeDev Calc.

Name_value1: the value or calculation to assign to Name1.

Name2; Name_value2;...: (optional) same as Name1 and Name_value1, respectively. Name_value2 must follow Name2 and so on.

Calculation: a formula expression that uses all names within the LET function.

Calculation must be the last argument in the LET function.

### Examples

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Hydrogen | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Atomic Number | 1 | 2 | 3 | ... | 118
4 | Relative Atomic Mass | 1.008 | 4.0026 | 6.94 | ... | 294

Calculate the molar mass of the water molecule knowing that the molecule has 2 hydrogen atoms and one oxygen atom.

=LET(mHydro; HLOOKUP("Hydrogen"; $A$1:$DO$4; 4; 0); mOxy; HLOOKUP("Oxygen"; $A$1:$DO$4; 4; 0); "The molar mass of water is "&(mOxy+2*mHydro)&" g/mol") returns "The molar mass of water is 18.015 g/mol".

#### Technical information

This function is available since LibreOfficeDev 24.8.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.LET

Related Topics

LET wiki page.

Please support us!