WORKDAY.INTL

Returnerer datoen beregnet fra en startdato med et spesifikt antall arbeidsdager, fĂžr eller etter startdatoen. Beregningen kan inkludere helger og helligdager som ikke-arbeidsdager.

Syntaks

ARBEIDSDAG.INTL(Startdato; dager [; helg [; helligdager]])

Startdato: er datoen fra nÄr beregningen er utfÞrt.

Dager er antall arbeidsdager. Positiv verdi for et resultat etter startdatoen, negativ verdi for et resultat fĂžr startdatoen.

Helg er en valgfri parameter – et tall eller en streng som brukes til Ă„ spesifisere ukedagene som er helgedager og ikke regnes som virkedager. Weekend er et helgenummer eller en streng som spesifiserer nĂ„r helger inntreffer. Helgetallverdier indikerer fĂžlgende helgedager:

Nummer 1 til 7 for to-dagers helger og 11 til 17 for en-dagers helger.

Antall

Helg

1 eller utelatt

LĂžrdag og SĂžndag

2

SĂžndag og Mandag

3

Mandag og Tirsdag

4

Tirsdag og Onsdag

5

Onsdag og Torsdag

6

Torsdag og Fredag

7

Fredag og LĂžrdag

11

Kun SĂžndag

12

Kun Mandag

13

Kun Tirsdag

14

Kun Onsdag

15

Kun Torsdag

16

Kun Fredag

17

Kun LĂžrdag


Helgestreng gir en annen mĂ„te Ă„ definere ukentlige ikke-arbeidsdager pĂ„. Den mĂ„ ha syv (7) tegn – nuller (0) for arbeidsdag og en (1) for ikke-arbeidsdag. Hvert tegn representerer en ukedag, som starter med mandag. Bare 1 og 0 er gyldige. "1111111" er en ugyldig streng og skal ikke brukes. For eksempel definerer helgestrengen "0000011" lĂžrdag og sĂžndag som ikke-arbeidsdager.

Helligdager er en valgfri liste over datoer som mÄ regnes som ikke-arbeidsdager. Listen kan gis i et celleomrÄde.

note

NÄr du legger inn datoer som en del av formler, er skrÄstreker eller bindestreker som brukes som dataseparatorer tolket som aritmetiske operatÞrer. Derfor blir datoer som er oppgitt i dette formatet, ikke anerkjent som datoer og resulterer i feilaktige beregninger. For Ä holde datoene tolket som deler av formler, bruk DATE-funksjonen, for eksempel DATE (1954; 7; 20), eller sett datoen i anfÞrselstegn og bruk ISO 8601-notasjonen, for eksempel "1954-07-20 ". UnngÄ Ä bruke lokalavhengige datoformater, for eksempel "07/20/54", kan beregningen gi feil hvis dokumentet er lastet inn under forskjellige lokale innstillinger.


tip

Entydig konvertering er mulig for ISO 8601 datoer og tider i deres utvidede formater med separatorer. Hvis en #VALUE! -feil oppstÄr, fjerner du deretter Generate #VALUE! feil i - LibreOfficeDev Calc - Formel Detaljer ... i avsnittet "Detaljert kalkulasjons Innstillinger", Konvertering fra tekst til tall listeboksen.


Eksempler

Hvilken dato kommer 20 virkedager etter 13. desember 2016? Skriv inn startdato i C3 og antall arbeidsdager i D3.

Helgeparameteren (tall) kan stĂ„ tom eller definert som 1 for standard helg (ikke-arbeidsdager) – LĂžrdag og SĂžndag.

Cellene F3 til J3 inneholder fem (5) helligdager for jul og nyttÄr i datoformat: 24. desember 2016; 25. desember 2016; 26. desember 2016; 31. desember 2016; og 1. januar 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returnerer 11. januar 2017 i resultatcellen, si D6 (bruk datoformat for cellen).

For Ă„ definere Fredag og LĂžrdag som helgedager, bruk helgeparameter 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returnerer 15. januar 2017 med helgeparameter 7.

For Ă„ definere sĂžndag kun helgedagen, bruk helgeparameter 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returnerer Januar 9, 2017.

Alternativt kan du bruke helgestrengen "0000001" for bare sĂžndag helg.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returnerer 9. januar 2017.

Funksjonen kan brukes uten de to valgfrie parameterne – ukedag og helligdager – ved Ă„ utelate dem:

=WORKDAY.INTL(C3;D3) gir resultatet: 10. januar 2017.

Teknisk informasjon

tip

Denne funksjonen har vĂŠrt tilgjengelig siden LibreOfficeDev 4.3.


Denne funksjonen er ikke en del av Open Document Format for Office-applikasjoner (OpenDocument) versjon 1.3. Del 4: Rekalkulert Formel (OpenFormula) Format-standard. Navnerommet er

COM.MICROSOFT.WORKDAY.INTL